RSS Widget – AS3

<?xml version="1.0" encoding="utf-8"?>
<m21m:rsswidget xmlns:m21m='http://www.m21m.com/schema/m21m'>
 <m21m:rssfeeds>
  <m21m:feed image="images/blogger.gif" feed="http://www.m21m.com/rss.xml" />
  <m21m:feed image="images/twitter.gif"
       feed="http://twitter.com/statuses/user_timeline/14305992.rss"/>
 </m21m:rssfeeds>
</m21m:rsswidget>

//import the Scroll class
import com.m21m.util.Scroll;
//add scrolling to the main_mc
var sb:Scroll = new Scroll(main_mc);
//total feeds to show per rss
var TOTALPERFEED = 6;
//be sure to change this.
var PROXY = "http://yoursite.com/proxy.php?url=";
//array to hold all the rss links from rss-widget.xml
var xmlManifest:Array = new Array();
 
//array to hold each XML file
var xmlDocs:Array = new Array();
 
//the XML file to be loaded.
var rssWidgetRequest:URLRequest = new URLRequest("xml/rss-widget.xml");
var urlLoader:URLLoader = new URLLoader();
 
//all my XML files
var docsXML:XML = new XML();
docsXML.ignoreWhitespace = true;
//load rss-widget.xml and when COMPLETE run function loadDocs
urlLoader.addEventListener(Event.COMPLETE,loadDocs);
urlLoader.load(rssWidgetRequest);
 
//images from the image attribute in m21m:feed image="images/twitter.gif"
var images:Array = new Array();
 
//load the docs
function loadDocs(event:Event):void {
 docsXML = XML(event.target.data);
 //m21m is the name space defined in my doc m21m:feed...
 var m21m:Namespace=docsXML.namespace("m21m");
 //get all the feed nodes
 var feeds=docsXML..m21m::feed;
 for (var i:int=0; i < feeds.length(); ++i) {
  //add images from the image attribute and add it to the images array
  images[images.length] = feeds[i].attribute("image");
  //add the feed to the xmlManifest array
  xmlManifest[xmlManifest.length] = feeds[i].attribute("feed");
 }
 //load the xml for each doc
 loadXMLDocs();
}
 
//load all the XML files
function loadXMLDocs() {
 if (xmlManifest.length>xmlDocs.length) {
 
  var rssURL:URLRequest = new URLRequest(PROXY+xmlManifest[xmlDocs.length]);
  var urlLoader:URLLoader = new URLLoader();
  var xmlDoc:XML = new XML();
  xmlDoc.ignoreWhitespace = true;
  urlLoader.addEventListener(Event.COMPLETE,getDoc);
  urlLoader.load(rssURL);
  function getDoc(event:Event) {
   xmlDoc = XML(event.target.data);
   //hold all the xml of each doc in an array
   xmlDocs[xmlDocs.length] = xmlDoc;
   loadXMLDocs();
  }
 } else {
  //create the feeds on the screen
  createFeeds();
 }
}
 
function createFeeds():void {
 for (var t:int=0; t < xmlDocs.length; t++) {
  //get the XML for the files
  docsXML = XML(xmlDocs[t]);
  //get all the item nodes from the rss feeds
  var xmlList=docsXML..item;
  var totalLength:int;
  //check to see how many nodes to display per each feed
  if (xmlList.length() < TOTALPERFEED) {
   totalLength = xmlList.length();
  } else {
   totalLength = TOTALPERFEED;
  }
  if (TOTALPERFEED >= 100) {
   totalLength = xmlList.length();
  }
  for (var i:int=0; i < totalLength; i++) {
   //add are feed movieclip from the library
   var feed_mc:Feed = new Feed();
   main_mc.content_mc.addChild(feed_mc);
   var loader =new Loader();
   loader.load(new URLRequest(images[t]));
   feed_mc.loader_mc.addChild(loader);
   feed_mc.feed_txt.htmlText = "<a href='"+xmlList[i].link.text()+"'>"+
           xmlList[i].title.text()+"</a>";
  }
 }
 //order the feeds on the screen
 orderFeeds();
 
 //garbage collection
 destroy();
}
 
 
function orderFeeds() {
 //loop through the movieclips and stack them
 for (var i:int=1; i < main_mc.content_mc.numChildren; i++) {
  main_mc.content_mc.getChildAt(i).y = main_mc.content_mc.getChildAt(i - 1).y +
            main_mc.content_mc.getChildAt(i - 1).height + 1;
 }
}
 
 
//delete all variables
function destroy() {
 xmlManifest = null;
 xmlDocs = null;
 rssWidgetRequest = null;
 urlLoader = null;
 docsXML = null;
 images = null;
}
 
//Custom Right Click Menu
var myMenu:ContextMenu = new ContextMenu();
myMenu.hideBuiltInItems();
//Add You Blog or Links to your site.
var menuItem:ContextMenuItem = new ContextMenuItem("www.m21m.com");
menuItem.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, goToURL);
myMenu.customItems.push(menuItem);
this.contextMenu = myMenu;
function goToURL(e:ContextMenuEvent):void {
 var url:String = "http://www.m21m.com";
 var request:URLRequest = new URLRequest(url);
 navigateToURL(request, '_blank');
}

import com.m21m.util.Scroll;
var sb:Scroll = new Scroll(main_mc);